;;; Tyreunom's system administration and configuration tools.

;;;

;;; Copyright © 2019 Julien Lepiller <julien@lepiller.eu>

;;;

;;; This program is free software: you can redistribute it and/or modify

;;; it under the terms of the GNU General Public License as published by

;;; the Free Software Foundation, either version 3 of the License, or

;;; (at your option) any later version.

;;;

;;; This program is distributed in the hope that it will be useful,

;;; but WITHOUT ANY WARRANTY; without even the implied warranty of

;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

;;; GNU General Public License for more details.

;;;

;;; You should have received a copy of the GNU General Public License

;;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

;;

;; OS template parts for different usages

;;

(define-module (config os)

  #:use-module (gnu packages admin)

  #:use-module (gnu packages android)

  #:use-module (gnu packages certs)

  #:use-module (gnu packages gnome)

  #:use-module (gnu packages linux)

  #:use-module (gnu packages openbox)

  #:use-module (gnu packages ssh)

  #:use-module (gnu packages tmux)

  #:use-module (gnu packages vim)

  #:use-module (gnu packages xdisorg)

  #:use-module (gnu packages xfce)

  #:use-module (gnu services)

  #:use-module (gnu services base)

  #:use-module (gnu services dbus)

  #:use-module (gnu services desktop)

  #:use-module (gnu services networking)

  #:use-module (gnu services ssh)

  #:use-module (gnu services virtualization)

  #:use-module (gnu services xorg)

  #:use-module (gnu system)

  #:use-module (gnu system accounts)

  #:use-module (gnu system file-systems)

  #:use-module (gnu system locale)

  #:use-module (gnu system shadow)

  #:use-module (guix gexp)

  #:export (server-services

            desktop-services

            tyreunom-os

	    tyreunom-desktop-os))

(define (server-services host-name)

  (cons*

    (console-keymap-service "fr-bepo")

    (service ntp-service-type)

    (service openssh-service-type

	     (openssh-configuration

	       (authorized-keys

		 `(("tyreunom" ,(local-file "../../keys/tyreunom.pub"))))))

    (modify-services %base-services

      (login-service-type config =>

        (login-configuration

          (inherit config)

          (motd (local-file (string-append "../../motd/" host-name)))))

      (guix-service-type config =>

        (guix-configuration

          (inherit config)

          (substitute-urls '("https://berlin.guixsd.org"

                             "https://mirror.hydra.gnu.org")))))))

(define bepo-evdev

  "Section \"InputClass\"

	Identifier \"evdev keyboard catchall\"

	Driver \"evdev\"

	MatchIsKeyboard \"on\"

	Option \"xkb_layout\" \"fr\"

	Option \"xkb_variant\" \"bepo\"

EndSection

Section \"InputClass\"

	Identifier \"touchpad\"

	MatchIsTouchpad \"on\"

	Driver \"synaptics\"

EndSection")

(define desktop-services

  (cons*

    (console-keymap-service "fr-bepo")

    (simple-service 'dconf dbus-root-service-type (list dconf))

    (service tor-service-type)

    (service qemu-binfmt-service-type

      (qemu-binfmt-configuration

	(platforms (lookup-qemu-platforms "arm" "aarch64" "i686" "ppc"))

	(guix-support? #t)))

    (modify-services %desktop-services

      (udev-service-type config =>

        (udev-configuration

	  (inherit config)

	  (rules (cons* android-udev-rules

			(udev-configuration-rules config)))))

      (slim-service-type config =>

        (slim-configuration

	  (inherit config)

	  (startx (xorg-start-command

		    #:configuration-file

		    (xorg-configuration-file

		      #:extra-config

		      (list bepo-evdev))))))

      (guix-service-type config =>

        (guix-configuration

          (inherit config)

          (substitute-urls '("https://berlin.guixsd.org"

                             "https://mirror.hydra.gnu.org")))))))

(define (tyreunom-os host-name)

  (operating-system

    (host-name host-name)

    (timezone "Europe/Paris")

    (locale "fr_FR.UTF-8")

    (bootloader #f)

    (file-systems %base-file-systems)

    (users (cons (user-account

                   (name "tyreunom")

                   (group "users")

                   (home-directory "/home/tyreunom"))

                 %base-user-accounts))

    (locale-definitions

      (cons (locale-definition

              (name "eo.utf8") (source "eo"))

            %default-locale-definitions))

    (hosts-file

      (plain-file "hosts"

        (string-append "127.0.0.1 lepiller.eu localhost " host-name "\n"

                       "::1       lepiller.eu localhost " host-name "\n"

                       %facebook-host-aliases)))

    (packages (cons* openssh tmux neovim nss-certs %base-packages))

    (services %base-services)))

(define (tyreunom-desktop-os host-name)

  (let ((system (tyreunom-os host-name)))

    (operating-system

      (inherit system)

      (users

	(map (lambda (user)

	       (if (equal? (user-account-name user) "tyreunom")

		   (user-account

		     (inherit user)

		     (supplementary-groups '("netdev" "adbusers" "audio" "video")))

		   user))

	     (operating-system-users system)))

      (groups (cons (user-group (system? #t) (name "adbusers"))

		    %base-groups))

      (packages (cons* xlockmore wpa-supplicant gvfs openbox xfce4-terminal

		       (operating-system-packages system))))))