* [Neovim](doc/neovim.md)

Neovim

======

Neovim is a fork of vim, a text editor.  This lets you configure it and manage

plugins.

Main Configuration

------------------

Neovim is configured by using the `neovim-home-type` service type.

**Scheme Procedure**: neovim-home-type

The type of service that generates configuration files for neovim.  Its value

is a neovim-configuration object.

**Data Type**: neovim-configuration

Data type that represents the Neovim configuration.  This data type has the

following fields:

* **init** (default *default-init*): the content of the `init.vim` file.  This

  is a list of strings and file-like objects.

* **plugins** (default '()): the list of plugins you wish to use.  They will

  be added to the top of the `init.vim` file.

Example Configuration

---------------------

```scheme

(user-home

  neovim-home-type

  (neovim-configuration

    (init '("set colorcolumn=80\n"))

    (plugins (list neovim-syntastic))))

```

;;; Guix Home Manager.

;;;

;;; Copyright ?? 2019 Julien Lepiller <julien@lepiller.eu>

;;;

;;; This program is free software: you can redistribute it and/or modify

;;; it under the terms of the GNU General Public License as published by

;;; the Free Software Foundation, either version 3 of the License, or

;;; (at your option) any later version.

;;;

;;; This program is distributed in the hope that it will be useful,

;;; but WITHOUT ANY WARRANTY; without even the implied warranty of

;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

;;; GNU General Public License for more details.

;;;

;;; You should have received a copy of the GNU General Public License

;;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

(define-module (home neovim)

  #:use-module (guix build utils)

  #:use-module (guix gexp)

  #:use-module (guix packages)

  #:use-module (guix records)

  #:use-module (gnu packages lxde)

  #:use-module (ice-9 match)

  #:use-module (srfi srfi-1)

  #:use-module (home)

  #:export (neovim-configuration

            neovim-configuration-init

            neovim-configuration-plugins

            default-init.vim

            neovim-home-type))

(define default-init.vim

  `(""))

(define-record-type* <neovim-configuration>

  neovim-configuration make-neovim-configuration

  neovim-configuration?

  (init    neovim-configuration-init

           (default default-init.vim))

  (plugins neovim-configuration-plugins

           (default '())))

(define neovim-home-type

  (home-type

    (name 'neovim)

    (extensions

      (list

        (home-extension

          (target root-home-type)

          (compute

            (lambda (config)

              (match config

                (($ <neovim-configuration> init plugins)

                 (let ((init.vim

                         (apply mixed-text-file "init.vim"

                                (append

                                  (fold

                                    (lambda (plugin result)

                                      (append

                                        result

                                        (list

                                          "set runtimepath+="

                                          (file-append plugin "/share/nvim/site")

                                          "\n")))

                                    '()

                                    plugins)

                                  init))))

                   `((".config/nvim/init.vim" ,init.vim))))))))))))