* [Tmux](doc/tmux.md)

Tmux

====

tmux is a terminal multiplexer. It lets you switch easily between

several programs in one terminal, detach them (they keep running in

the background) and reattach them to a different terminal.

Main Configuration

------------------

Tmux is configured by using the `tmux-home-type` service type.

**Scheme Procedure**: tmux-home-type

The type of service that generates configuration files for tmux.  Its value

is a tmux-configuration object.

**Data Type**: tmux-configuration

Data type that represents the Tmux configuration.  This data type has the

following fields:

* **terminal** (default "screen-256color"): set environment variable

  `TERM`.

* **prefix** (default #f): For keys that control tmux itself. if `#f`

  use default prefix.

* **mode-keys** (default "vi"): VI or Emacs style shortcuts.

* **escapeTime** (default 500): Time in milliseconds for which tmux

  waits after an escape is input.

* **history-limit** (default 2000): Maximum number of lines held in

  window history.

* **mouse?** (default #f): Whether to use mouse.

* **clock24?** (default #f): Whether to use 24 hour clock.

* **extra-conf** (default '("")):  This is a list of strings and

  file-like objects.

Example Configuration

---------------------

```scheme

(user-home

  tmux-home-type

  (tmux-configuration

    (terminal "xterm-256color")

    (prefix "F12")

    (mode-keys "emacs")

    (escapeTime 700)

    (history-limit 5000)

    (mouse? #t)

    (clock24? #t)

    (extra-conf (list "set -g set-titles on\n")))

```

;;; Guix Home Manager.

;;;

;;; Copyright ?? 2020 Z572 <873216071@qq.com>

;;;

;;; This program is free software: you can redistribute it and/or modify

;;; it under the terms of the GNU General Public License as published by

;;; the Free Software Foundation, either version 3 of the License, or

;;; (at your option) any later version.

;;;

;;; This program is distributed in the hope that it will be useful,

;;; but WITHOUT ANY WARRANTY; without even the implied warranty of

;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

;;; GNU General Public License for more details.

;;;

;;; You should have received a copy of the GNU General Public License

;;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

(define-module (home tmux)

  #:use-module (guix build utils)

  #:use-module (guix gexp)

  #:use-module (guix records)

  #:use-module (ice-9 match)

  #:use-module (home)

  #:export (tmux-configuration

            tmux-configuration-terminal

            tmux-configuration-prefix

            tmux-configuration-mode-keys

            tmux-configuration-escapeTime

            tmux-configuration-history-limit

            tmux-configuration-mouse?

            tmux-configuration-clock24?

            tmux-configuration-extra-conf

            tmux-home-type))

(define-record-type* <tmux-configuration>

  tmux-configuration make-tmux-configuration

  tmux-configuration?

  (terminal tmux-configuration-terminal

            (default "screen-256color"))

  (prefix tmux-configuration-prefix

          (default #f))

  (mode-keys tmux-configuration-mode-keys

             (default "vi"))

  (escapeTime tmux-configuration-escapeTime

              (default 500))

  (history-limit tmux-configuration-history-limit

                 (default 2000))

  (mouse? tmux-configuration-mouse?

          (default #f))

  (clock24? tmux-configuration-clock24?

            (default #f))

  (extra-conf tmux-configuration-extra-conf

              (default '(""))))

(define tmux-home-type

  (home-type

   (name 'tmux)

   (extensions

    (list

     (home-extension

      (target root-home-type)

      (compute

       (match-lambda

         (($ <tmux-configuration>

             terminal

             prefix

             mode-keys

             escapeTime

             history-limit

             mouse?

             clock24?

             extra-conf)

          (let ((tmux.conf

                 (apply mixed-text-file "tmux.conf"

                        (cons* (format #f "

~{setw -g ~a ~S\n~}

~{set -g ~a ~S\n~}

~a

"

                                       `("clock-mode-style"

                                         ,(if clock24? "24" "12"))

                                       `("escape-time" ,escapeTime

                                         "history-limit" ,history-limit

                                         "default-terminal" ,terminal

                                         "status-keys" ,mode-keys

                                         "mode-keys" ,mode-keys

                                         "mouse" ,(if mouse? "on" "off"))

                                       (if (eq? #f prefix)

                                           ""

                                           (string-append

                                            "unbind C-b\n"

                                            "set -g prefix " prefix)))

                               extra-conf))))

            `((".tmux.conf" ,tmux.conf)))))))))))