;;; Nani Project website

;;; Copyright © 2020 Julien Lepiller <julien@lepiller.eu>

;;;

;;; This file is part of the Nani Project website.

;;;

;;; The Nani Project website is free software; you can redistribute it and/or modify it

;;; under the terms of the GNU Affero General Public License as published by

;;; the Free Software Foundation; either version 3 of the License, or (at

;;; your option) any later version.

;;;

;;; The Nani Project website is distributed in the hope that it will be useful, but

;;; WITHOUT ANY WARRANTY; without even the implied warranty of

;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the

;;; GNU Affero General Public License for more details.

;;;

;;; You should have received a copy of the GNU Affero General Public License

;;; along with the Nani Project website.  If not, see <http://www.gnu.org/licenses/>.

(use-modules (nani jmdict trie))

(use-modules (nani jmdict serialize))

(use-modules (nani wadoku xml))

(use-modules (nani wadoku pitch))

(use-modules (nani frequency))

(use-modules (nani trie))

(use-modules (nani result))

(use-modules (ice-9 match))

(use-modules (ice-9 binary-ports))

;; Break these steps to try and let the GC reclaim these big objects

(define (get-results1 input frq)

  (call-with-input-file input

    (lambda (port)

      (xml->results port frq))))

(define (get-results input sense-filter frq)

  (let* ((results (get-results1 input frq))

         (results (map (lambda (result)

                         (update-result

                           result

                           #:senses (filter sense-filter

                                            (result-senses result))))

                       results))

         (results (filter (lambda (result) (not (null? (result-senses result))))

                          results)))

    results))

(define (compile input sense-filter output)

  (let* ((results (get-results input sense-filter

                               (load-frequency "dictionaries/frequency.tsv")))

         (kanji-trie (compress-trie (make-kanji-trie results)))

         (reading-trie (compress-trie (make-reading-trie results)))

         (meaning-trie (compress-trie (make-meaning-trie results))))

    (format #t "Number of entries in ~a: ~a~%" output (length results))

    (call-with-output-file output

      (lambda (port)

        (put-bytevector port

          (serialize-jmdict results kanji-trie reading-trie meaning-trie))))))

(define (get-pitch input)

  (call-with-input-file input

    (lambda (port)

      (xml->pitch port))))

(define (pitch input output)

  (let ((results (get-pitch input)))

    (format #t "~a results." (length results))

    (call-with-output-file output

      (lambda (port)

        (put-bytevector port

          (serialize-pitch results))))))

(match (command-line)

  ((_ cmd input output)

   (cond

    ((equal? cmd "build")

     (compile input (const #t) output))

    ((equal? cmd "pitch")

     (pitch input output))

    (else (format #t "Unknown cmd ~a.~%" cmd)))))