configure.ac
| 1 | dnl -*- Autoconf -*- |
| 2 | |
| 3 | AC_INIT([Guile-Z3], [0.1.0], |
| 4 | [julien@lepiller.eu], [guile-Z3], |
| 5 | [https://framagit.org/tyreunom/guile-z3]) |
| 6 | |
| 7 | AC_CONFIG_SRCDIR([z3.scm.in]) |
| 8 | AC_CONFIG_AUX_DIR([build-aux]) |
| 9 | AM_INIT_AUTOMAKE([foreign color-tests -Wall -Wno-portability]) |
| 10 | AM_SILENT_RULES([yes]) |
| 11 | |
| 12 | dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.) |
| 13 | dnl Make sure they are available. |
| 14 | m4_pattern_forbid([PKG_CHECK_MODULES]) |
| 15 | m4_pattern_forbid([GUILE_PKG]) |
| 16 | |
| 17 | GUILE_PKG([3.0 2.2 2.0]) |
| 18 | GUILE_PROGS |
| 19 | |
| 20 | AC_SUBST([Z3_LIBDIR]) |
| 21 | |
| 22 | AC_MSG_CHECKING([whether we have libz3]) |
| 23 | if test "x$Z3_LIBDIR" = "x"; then |
| 24 | AC_MSG_RESULT([no]) |
| 25 | AC_MSG_ERROR([failed to find libz3, please specify Z3_LIBDIR on the command-line.]) |
| 26 | else |
| 27 | AC_MSG_RESULT([yes]) |
| 28 | fi |
| 29 | |
| 30 | if test "$cross_compiling" = "no"; then |
| 31 | AC_MSG_CHECKING([whether '$Z3_LIBDIR/libz3' is usable]) |
| 32 | GUILE_CHECK([retval], |
| 33 | [(dynamic-func \"Z3_mk_config\" |
| 34 | (dynamic-link \"$Z3_LIBDIR/libz3\"))]) |
| 35 | if test "$retval" != 0; then |
| 36 | AC_MSG_RESULT([no]) |
| 37 | AC_MSG_ERROR([failed to load '$Z3_LIBDIR/libz3']) |
| 38 | else |
| 39 | AC_MSG_RESULT([yes]) |
| 40 | fi |
| 41 | else |
| 42 | GUILE_TARGET="--target=$host_alias" |
| 43 | AC_SUBST([GUILE_TARGET]) |
| 44 | fi |
| 45 | |
| 46 | AC_CONFIG_FILES([Makefile z3.scm]) |
| 47 | AC_CONFIG_FILES([env], [chmod +x env]) |
| 48 | |
| 49 | AC_OUTPUT |
| 50 |