dnl -*- Autoconf -*-

AC_INIT([Guile-fediverse], [0.1.0],

  [julien@lepiller.eu], [guile-fediverse],

  [https://framagit.org/tyreunom/guile-fediverse])

AC_CONFIG_AUX_DIR([build-aux])

AM_INIT_AUTOMAKE([foreign color-tests -Wall -Wno-portability])

AM_SILENT_RULES([yes])

dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)

dnl Make sure they are available.

m4_pattern_forbid([PKG_CHECK_MODULES])

m4_pattern_forbid([GUILE_PKG])

GUILE_PKG([3.0 2.2 2.0])

GUILE_PROGS

GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])

if test "x$have_guile_json" != "xyes"; then

  AC_MSG_ERROR([Guile-Json could not be found; please install it.])

fi

GUILE_MODULE_AVAILABLE([have_guile_jsonld], [(jsonld json)])

if test "x$have_guile_jsonld" != "xyes"; then

  AC_MSG_ERROR([Guile-JsonLD could not be found; please install it.])

fi

AC_ARG_VAR([SCHEMA_ORG_FILE],

            AS_HELP_STRING([SCHEMA_ORG_FILE],

                           [Specify a file that contains the description of the

schema.org vocabulary, in the jsonld format.  When not set, the online version

is downloaded during the build.]))

if test "x$SCHEMA_ORG_FILE" != "x"; then

  if test -f "$SCHEMA_ORG_FILE"; then

    AC_MSG_NOTICE([The specified schema.org description file will be used.])

  else

    AC_MSG_ERROR([Specified schema.org description does not exist.])

  fi

fi

AC_CONFIG_FILES([Makefile])

AC_CONFIG_FILES([env], [chmod +x env])

AC_REQUIRE_AUX_FILE([tap-driver.sh])

AC_OUTPUT