dnl -*- Autoconf -*-

AC_INIT([Guile-Z3], [0.1.0],
  [julien@lepiller.eu], [guile-Z3],
  [https://framagit.org/tyreunom/guile-z3])

AC_CONFIG_SRCDIR([z3.scm.in])
AC_CONFIG_AUX_DIR([build-aux])
AM_INIT_AUTOMAKE([foreign color-tests -Wall -Wno-portability])
AM_SILENT_RULES([yes])

dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
dnl Make sure they are available.
m4_pattern_forbid([PKG_CHECK_MODULES])
m4_pattern_forbid([GUILE_PKG])

GUILE_PKG([3.0 2.2 2.0])
GUILE_PROGS

AC_SUBST([Z3_LIBDIR])

AC_MSG_CHECKING([whether we have libz3])
if test "x$Z3_LIBDIR" = "x"; then
   AC_MSG_RESULT([no])
   AC_MSG_ERROR([failed to find libz3, please specify Z3_LIBDIR on the command-line.])
else
   AC_MSG_RESULT([yes])
fi

if test "$cross_compiling" = "no"; then
   AC_MSG_CHECKING([whether '$Z3_LIBDIR/libz3' is usable])
   GUILE_CHECK([retval],
   [(dynamic-func \"Z3_mk_config\"
                 (dynamic-link \"$Z3_LIBDIR/libz3\"))])
   if test "$retval" != 0; then
      AC_MSG_RESULT([no])
      AC_MSG_ERROR([failed to load '$Z3_LIBDIR/libz3'])
   else
      AC_MSG_RESULT([yes])
   fi
else
   GUILE_TARGET="--target=$host_alias"
   AC_SUBST([GUILE_TARGET])
fi

AC_CONFIG_FILES([Makefile z3.scm])
AC_CONFIG_FILES([env], [chmod +x env])

AC_OUTPUT